Ganponブログ

趣味の模型作り、ドライブ、旅行など
since Mar.2017

RC可動化 1/35 ドラゴン T34/85 スケッチ＆回路（更新）

2024-09-12 22:33:11 | 1/35 ドラゴン T-34/85
リクエストが有りましたので、T34のスケッチと回路図を公開します。
久しぶりにT34を動かしてみて、気になるところを変更して動作を確認しました。
▼先日のスケッチに手を入れ変更後のスケッチを公開します。
2024-09-12 更新　IRremote Ver.2.2.3より2.8.0の方が安定しています。
メモリー容量ギリギリなのでIDEやライブラリのバージョンを調整しました。


 
  1. /* PS3BT_arduino_NANO_tank_TB6612_IRw_MP3_T34spec3c
  2.   2024-09-11
  3.   砲塔旋回サーボ停止追加 detach()
  4.   モータドライバはTB6612
  5.   砲撃時のリコイルアクション
  6.   irremote PIN3　赤外線発光（砲撃）システム
  7.   A0ピンに赤外線受光モジュール出力を接続し、被弾処理を追加
  8.   主砲発光はミニUSBシールドのGPOUTピン0を使用
  9.   機銃主砲発光はミニUSBシールドのGPOUTピン1を使用
  10.   ヘッドライトはミニUSBシールドのGPOUTピン2を使用
  11.   MP3プレーヤーで効果音を発生

  13.   開発環境
  14.   Arduino 1.8.19
  15.   IRremote Ver.2.8.0
  16.   DFRobotDFPlayerMini.h 1.0.5
  17.   USBホストシールド 2.0 1.20

  19.   スケッチが使用できるメモリが少なくなっています。動作が不安定になる可能性があります。
  20.   最大30720バイトのフラッシュメモリのうち、スケッチが30282バイト（98%）を使っています。
  21.   最大2048バイトのRAMのうち、グローバル変数が1626バイト（79%）を使っていて、
  22.   ローカル変数で422バイト使うことができます。
  23.   
  24. */

  26. #include <SoftwareSerial.h>
  27. #include <DFRobotDFPlayerMini.h>
  28. SoftwareSerial mySerial(A2, A3); // DFPlayer TX,RX
  29. DFRobotDFPlayerMini myDFPlayer;

  31. #include <PS3BT.h>
  32. #include <usbhub.h>
  33. #ifdef dobogusinclude
  34. #include <spi4teensy3.h>
  35. #endif
  36. //#include <Usb.h> // needed by Arduino IDE
  37. #include <USB_Host_Shield_GPIO.h> // GPOUTピンで主砲LEDを発光させるため 1.20
  38. MaxGPIO max;

  40. USB Usb;
  41. BTD Btd(&Usb);
  42. PS3BT PS3(&Btd);
  43. //PS3BT PS3(&Btd, 0x00, 0x1B, 0xDC, 0xF2, 0x53, 0xFA); //for Dongke B
  44. /*シリアルモニタにBluetooth DongleのアドレスがSerial.printされる。
  45.   書き出された6個のコードをスケッチを変更し、
  46.   ドングルを指した状態でArduinoに書き込む（電源は切らない）
  47.   ドングルを抜いてUSBケーブルでPS3コントローラを接続する（電源は切らない）
  48.   ケーブルを抜いてドングルを指し直す（Arduinoを再起動する）
  49.   PS3コントローラのPS ボタンを押してペアリングする。
  50. */

  52. #include <IRremote.h>
  53. IRsend irsend;
  54. int RECV_PIN = A0 ; //赤外線受光部をPIN A0に
  55. IRrecv irrecv(RECV_PIN);
  56. decode_results results; //受信信号を格納する
  57. const long sign_hit = 0x4CB0FADD;
  58. int cnt = 0 ;

  60. #include <VarSpeedServo.h>
  61. VarSpeedServo myservo_1;
  62. VarSpeedServo myservo_2;
  63. int servo_1pos = 75;
  64. const int servo1_sp = 20;
  65. const int servo2_sp = 5;
  66. int ch = 0;
  67. int pos_y;
  68. int pos_x;
  69. int pos_ry;
  70. int pos_rx;
  71. int PWMA = 5; // Aモータ PWM 左側モータ
  72. int AIN1 = 4; // Aモータ IN1 （ 9ピンはUSBホストシールド使用
  73. int AIN2 = 2; // Aモータ IN2
  74. int BIN1 = 8; // Bモータ IN1
  75. int BIN2 = 7; // Bモータ IN2
  76. int PWMB = 6; // Bモータ PWM 右側モータ（ 10ピンはUSBホストシールド使用

  78. int motor_speed;
  79. int steering;
  80. const int LED_3 = A1 ; //ブレーキランプ

  82. void setup() {
  83.   irrecv.enableIRIn(); // Start the receiver
  84.   pinMode(RECV_PIN, INPUT) ; // 赤外線受信モジュールに接続ピンをデジタル入力に設定
  85.   pinMode(PWMA, OUTPUT);
  86.   pinMode(AIN1, OUTPUT);
  87.   pinMode(AIN2, OUTPUT);
  88.   pinMode(BIN1, OUTPUT);
  89.   pinMode(BIN2, OUTPUT);
  90.   pinMode(PWMB, OUTPUT);
  91.   pinMode(LED_3, OUTPUT);
  92.   pinMode(A4, OUTPUT);
  93.   pinMode(A5, OUTPUT);
  94.   myservo_1.attach(A4); //servo1 砲身上下
  95.   myservo_1.write(servo_1pos);
  96.   myservo_1.detach();
  97.   myservo_2.attach(A5); //servo2　砲塔旋回
  98.   myservo_2.write(90);

  100.   Serial.begin (115200);
  101.   mySerial.begin (9600);
  102.   myDFPlayer.begin(mySerial);
  103.   myDFPlayer.volume(20); //Set volume value (0~30)

  105.   while (!Serial); // Wait for serial port to connect - used on Leonardo, Teensy and other boards with built-in USB CDC serial connection
  106.   if (Usb.Init() == -1) {
  107.     Serial.print(F("\r\nOSC did not start"));
  108.     while (1); //halt
  109.   }
  110.   Serial.print(F("\r\nPS3 Bluetooth Library Started"));
  111. }

  113. void loop() {
  114.   Usb.Task();
  115.   if (PS3.PS3Connected) {
  116.     if (irrecv.decode(&results)) { // 受信コードの値が
  117.       if (results.value == sign_hit) { // 0x4CB0FADDだったら被弾
  118.         Hit();
  119.       }
  120.       irrecv.resume();
  121.     }

  123.     //砲身　UP/DOWN
  124.     if ( PS3.getButtonClick(R3)) { //CENTER
  125.       myservo_1.attach(A4);
  126.       myservo_1.write(servo_1pos, servo1_sp, true);
  127.       // myservo_1.detach();
  128.     }
  129.     pos_ry = PS3.getAnalogHat(RightHatY);
  130.     if (pos_ry < 10) { // UP
  131.       myservo_1.attach(A4);
  132.       myservo_1.write(servo_1pos - 30, servo1_sp, true);
  133.       // myservo_1.detach();
  134.     } else if (pos_ry > 245) { //DOWN
  135.       myservo_1.attach(A4);
  136.       myservo_1.write(servo_1pos + 30, servo1_sp, true);
  137.       // myservo_1.detach();
  138.     } else { //停止
  139.       myservo_1.detach();
  140.     }

  142.     //砲塔旋回
  143.     if ( PS3.getAnalogHat(LeftHatX) > 230) { //右旋回
  144.       myservo_2.attach(A5);
  145.       myservo_2.write(100, servo2_sp);
  146.     } else if (PS3.getAnalogHat(LeftHatX) < 26) { //左旋回
  147.       myservo_2.attach(A5);
  148.       myservo_2.write(80, servo2_sp);
  149.     } else { //停止
  150.       //myservo_2.attach(A5);
  151.       myservo_2.write(90, 255, true);
  152.       myservo_2.detach();
  153.     }

  155.     //砲撃 + リコイル
  156.     if (PS3.getButtonClick(R1) && ch == 0 ) {
  157.       int khz = 38; // 38kHz carrier frequency for the NEC protocol
  158.       unsigned int irSignal[] = {4100, 1000, 2000, 2050, 1000}; // vs BATTLE TANK jr T-72 40MHz
  159.       // AnalysIR Batch Export (IRremote) - RAW
  160.       irsend.sendRaw(irSignal, (sizeof(irSignal) / sizeof(irSignal[0])), khz);
  161.       //irsend.sendRaw(data buf, length, hertz)
  162.       irrecv.enableIRIn(); // 受信を再開する　　
  163.       max.write(0, HIGH); //主砲発光
  164.       myDFPlayer.play(15);

  166.       delay(200);
  167.       motor_run(128, 0, 1, 128, 0, 1, 1);
  168.       ch = 5000; //約2秒間は砲撃不可
  169.       delay(100);
  170.       motor_run(0, 0, 0, 0, 0, 0, 1);
  171.       delay(200);
  172.       max.write(0, LOW);
  173.       motor_run(64, 1, 0, 64, 1, 0, 1);
  174.       delay(260);
  175.     } else {
  176.       if (ch > 0) {
  177.         ch--;
  178.       }
  179.     }

  181.     //銃撃
  182.     if ( PS3.getButtonClick(L1)) {
  183.       //mp3_play (10);
  184.       myDFPlayer.play(10);
  185.       delay(200);
  186.       for ( int i = 0; i < 5 ; i++) {
  187.         max.write(1, HIGH);
  188.         delay(100);
  189.         max.write(1, LOW);
  190.         delay(80);
  191.       }
  192.     }

  194.     //ヘッドライト
  195.     if (PS3.getButtonClick(RIGHT)) { //点灯
  196.       max.write(2, HIGH);
  197.     } else if (PS3.getButtonClick(LEFT)) { //消灯
  198.       max.write(2, LOW);
  199.     }

  201.     //走行コントロール
  202.     pos_y = PS3.getAnalogHat(LeftHatY);
  203.     pos_x = PS3.getAnalogHat(RightHatX);

  205.     //前進
  206.     if (pos_y <= 102 && pos_x >= 102 && pos_x <= 152) {
  207.       motor_speed = map(pos_y, 102, 0, 0, 180);
  208.       motor_run(motor_speed, 1, 0, motor_speed, 1, 0, 0);
  209.     }

  211.     //後進
  212.     else if ( pos_y >= 152 && pos_x >= 102 && pos_x <= 152) {
  213.       motor_speed = map(pos_y, 152, 255, 0, 180);
  214.       motor_run(motor_speed, 0, 1, motor_speed, 0, 1, 0);
  215.     }

  217.     //前進右緩旋回、信地旋回
  218.     else if ( pos_y <= 102 && pos_x > 152) {
  219.       motor_speed = map(pos_y, 102, 0, 0, 180);
  220.       steering = motor_speed * (1.00 - (map(pos_x, 152, 255, 0, 255) / 255.00));
  221.       motor_run(motor_speed, 1, 0, steering, 1, 0, 0);
  222.     }

  224.     //前進左旋回、信地旋回
  225.     else if ( pos_y < 102 && pos_x < 102) {
  226.       motor_speed = map(pos_y, 102, 0, 0, 180);
  227.       steering = motor_speed * (1.00 - (map(pos_x, 102, 0, 0, 255) / 255.00));
  228.       motor_run(steering, 1, 0, motor_speed, 1, 0, 0);
  229.     }

  231.     //後進右旋回、信地旋回
  232.     else if ( pos_y > 152 && pos_x > 152) {
  233.       motor_speed = map(pos_y, 152, 255, 0, 180);
  234.       steering = motor_speed * (1.00 - (map(pos_x, 152, 255, 0, 255) / 255.00));
  235.       motor_run(motor_speed, 0, 1, steering, 0, 1, 0);
  236.     }

  238.     //後進左旋回、信地旋回
  239.     else if ( pos_y > 152 && pos_x < 102) {
  240.       motor_speed = map(pos_y, 152, 255, 0, 180);
  241.       steering = motor_speed * (1.00 - (map(pos_x, 102, 0, 0, 255) / 255.00));
  242.       motor_run(steering, 0, 1, motor_speed, 0, 1, 0);
  243.     }

  245.     //右超信地旋回
  246.     else if ( pos_x > 245 && pos_y >= 102 && pos_y <= 152) {
  247.       motor_speed = 90;
  248.       motor_run(motor_speed, 1, 0, motor_speed, 0, 1, 0);
  249.     }

  251.     //左超信地旋回
  252.     else if ( pos_x < 10 && pos_y >= 102 && pos_y <= 152) {
  253.       motor_speed = 90;
  254.       motor_run(motor_speed, 0, 1, motor_speed, 1, 0, 0);
  255.     }

  257.     else { //停止
  258.       motor_run(0, 1, 1, 0, 1, 1, 1);
  259.     }
  260.   }
  261. }


  264. void motor_run(int D0, int D1, int D2, int D3, int D4, int D5, int D6) {
  265.   /* D0 : モータスピード（左）
  266.      D1 : モータA（左）CH1 , D2 : モータA（左）CH2 1 = HIGH / 0 = LOW
  267.      D3 : モータスピード（右）
  268.      D4 : モータB（右）CH1 , D5 : モータB（右）CH2 1 = HIGH / 0 = LOW
  269.      D6 : LED_3 ON/OFF 1 = HIGH / 0 = LOW
  270.   */
  271.   analogWrite(PWMA, D0);
  272.   digitalWrite(AIN1, D1);
  273.   digitalWrite(AIN2, D2);
  274.   analogWrite(PWMB, D3);
  275.   digitalWrite(BIN1, D4);
  276.   digitalWrite(BIN2, D5);
  277.   digitalWrite(LED_3, D6);
  278. }

  280. // ====被弾====
  281. void Hit() {
  282.   motor_run(255, 0, 1, 255, 1, 0, 0); //左超信地旋回
  283.   delay(100);
  284.   motor_run(0, 1, 1, 0, 1, 1, 1); //停止
  285.   delay(50);
  286.   motor_run(255, 1, 0, 255, 0, 1, 0); //右超信地旋回
  287.   delay(100);
  288.   motor_run(0, 1, 1, 0, 1, 1, 1); //停止
  289.   delay(50);
  290.   /*
  291.     motor_run(128, 1, 0, 1, 0, 0);　 //前進
  292.     delay(50);
  293.     motor_run(0, 1, 1, 1, 1, 1); //停止
  294.     delay(50);
  295.   */
  296.   cnt++;
  297.   if ( cnt >= 5 ) {
  298.     motor_run(0, 1, 1, 0, 1, 1, 0); //停止
  299.     delay(30000); //復活までに30秒
  300.     cnt = 0;
  301.   } else {
  302.     delay(1000);
  303.   }
  304. }


コメントを投稿