λ、Zを複素数とし、λ=LR+iLI , Z=X+iYとする。
今、任意の複素関数：F(Z)として、
また複素関数： K(Z,λ)=(sinλ)F(Z)-1/((sinλ)F(Z)) とする。
ここで、巡回式：Z←K(Z,λ)を考える。
Zの初期値をZ0とする。最大巡回回数をNmaxとする。
この巡回式で、X^2+Y^2＞T(実定数)のとき、巡回ループを抜け出すとする。
今、λの複素平面領域：LRS＜=LR＜=LRE,LIS＜=LI＜=LIE の各点において、
Z←K(Z,λ)を実行する。此のループを貫通した場合、該当点を黄色とする。ループを抜け出した時の巡回回数をNoとして、其の該当点を以下の色とする。C=No mod 16,C=7→8,6→5。
またdLR=(LRE-LRS)/640,dLI=dLR,LIS=-240*dLI,LIE=240*dLIとする。
***
下図は以下のF(Z)の画像である。
F(Z)=sinZ, cosZ, tanZ, sinhZ, sinsinZ, e^Z, e^sinZ, e^tanZ
K(Z,λ)=(sinλ)F(Z)-1/((sinλ)F(Z))
各F(Z)画像の条件は画像に書いてある。
また、これらの図の最後に、F(Z)=sinZの場合のBASIC/98のプログラムを書いておく。
------------------------------------------------------------
001-008
-------------------------------------------------------------
F(Z)=sinZの場合のBASIC/98のプログラムを以下に示す。
10 REM K(Z,λ)=sinλF(Z)-1/sinλF(Z))
20 REM λ=LR+iLI, F(Z)=FR+iFI
30 REM sinλ=sin(LR+iLI)=sin(LR)ch(LI)+icos(LR)sh(LI)
40 REM 横軸(K)：640 dots、縦軸(J)：480 dots
50 CONSOLE ,,0,1
60 COLOR 0,7,,,2
70 CLS 3
80 CHAIN MERGE "C:\BASIC1\PRO\SUBR\KOSHIKI.BAS",90,ALL
90 CHAIN MERGE "C:\BASIC1\PRO\SUBR\ER1.BAS",100,ALL
100 ON ERROR GOTO 50000
110 GOSUB 10000
120 OPEN "C:\BASIC1\RUN\DATA.DAT" FOR OUTPUT AS #1
130 OPEN "C:\BASIC1\RUN\親DATA.DAT" FOR OUTPUT AS #2
140 REM 親DATAの設定(随時変更)
150 LRS=0 :LRE=P :DR=(LRE-LRS)/640:DI=DR
160 LIS=-240*DI:LIE=-LIS
170 WRITE #2,LRS,LRE,LIS,LIE,DR,DI
180 '
190 CLOSE #2
200 FOR J=0 TO 480
210 LOCATE 0,0:PRINT J
220 LI=LIS+DI*J
230 FOR K=0 TO 640
240 X=0.5 :Y=0
250 LR=LRS+DR*K
260 FOR N=0 TO 15
270 FR=FNSINR(X,Y)
280 FI=FNSINI(X,Y)
281 '
290 A1=SIN(LR)*FNCOSH(LI)*FR-COS(LR)*FNSINH(LI)*FI
300 A2=SIN(LR)*FNCOSH(LI)*FI+COS(LR)*FNSINH(LI)*FR
301 '
310 A33=A1^2+A2^2
320 IF A33=0 THEN 390
330 A3=1/A33
340 JR=A1*(1-A3)
350 JI=A2*(1+A3)
360 X=JR : Y=JI
370 Q=X^2+Y^2
380 IF Q>50 THEN 410
390 NEXT N
400 C=6:GOTO 450
410 '発散時のPSET
420 C=N MOD 16
430 IF C=7 THEN C=8
440 IF C=6 THEN C=5
450 PSET (K,J),C
460 WRITE #1,K,J,C,N
470 NEXT K
480 NEXT J
500 END
今、任意の複素関数：F(Z)として、
また複素関数： K(Z,λ)=(sinλ)F(Z)-1/((sinλ)F(Z)) とする。
ここで、巡回式：Z←K(Z,λ)を考える。
Zの初期値をZ0とする。最大巡回回数をNmaxとする。
この巡回式で、X^2+Y^2＞T(実定数)のとき、巡回ループを抜け出すとする。
今、λの複素平面領域：LRS＜=LR＜=LRE,LIS＜=LI＜=LIE の各点において、
Z←K(Z,λ)を実行する。此のループを貫通した場合、該当点を黄色とする。ループを抜け出した時の巡回回数をNoとして、其の該当点を以下の色とする。C=No mod 16,C=7→8,6→5。
またdLR=(LRE-LRS)/640,dLI=dLR,LIS=-240*dLI,LIE=240*dLIとする。
***
下図は以下のF(Z)の画像である。
F(Z)=sinZ, cosZ, tanZ, sinhZ, sinsinZ, e^Z, e^sinZ, e^tanZ
K(Z,λ)=(sinλ)F(Z)-1/((sinλ)F(Z))
各F(Z)画像の条件は画像に書いてある。
また、これらの図の最後に、F(Z)=sinZの場合のBASIC/98のプログラムを書いておく。
------------------------------------------------------------
001-008
-------------------------------------------------------------
F(Z)=sinZの場合のBASIC/98のプログラムを以下に示す。
10 REM K(Z,λ)=sinλF(Z)-1/sinλF(Z))
20 REM λ=LR+iLI, F(Z)=FR+iFI
30 REM sinλ=sin(LR+iLI)=sin(LR)ch(LI)+icos(LR)sh(LI)
40 REM 横軸(K)：640 dots、縦軸(J)：480 dots
50 CONSOLE ,,0,1
60 COLOR 0,7,,,2
70 CLS 3
80 CHAIN MERGE "C:\BASIC1\PRO\SUBR\KOSHIKI.BAS",90,ALL
90 CHAIN MERGE "C:\BASIC1\PRO\SUBR\ER1.BAS",100,ALL
100 ON ERROR GOTO 50000
110 GOSUB 10000
120 OPEN "C:\BASIC1\RUN\DATA.DAT" FOR OUTPUT AS #1
130 OPEN "C:\BASIC1\RUN\親DATA.DAT" FOR OUTPUT AS #2
140 REM 親DATAの設定(随時変更)
150 LRS=0 :LRE=P :DR=(LRE-LRS)/640:DI=DR
160 LIS=-240*DI:LIE=-LIS
170 WRITE #2,LRS,LRE,LIS,LIE,DR,DI
180 '
190 CLOSE #2
200 FOR J=0 TO 480
210 LOCATE 0,0:PRINT J
220 LI=LIS+DI*J
230 FOR K=0 TO 640
240 X=0.5 :Y=0
250 LR=LRS+DR*K
260 FOR N=0 TO 15
270 FR=FNSINR(X,Y)
280 FI=FNSINI(X,Y)
281 '
290 A1=SIN(LR)*FNCOSH(LI)*FR-COS(LR)*FNSINH(LI)*FI
300 A2=SIN(LR)*FNCOSH(LI)*FI+COS(LR)*FNSINH(LI)*FR
301 '
310 A33=A1^2+A2^2
320 IF A33=0 THEN 390
330 A3=1/A33
340 JR=A1*(1-A3)
350 JI=A2*(1+A3)
360 X=JR : Y=JI
370 Q=X^2+Y^2
380 IF Q>50 THEN 410
390 NEXT N
400 C=6:GOTO 450
410 '発散時のPSET
420 C=N MOD 16
430 IF C=7 THEN C=8
440 IF C=6 THEN C=5
450 PSET (K,J),C
460 WRITE #1,K,J,C,N
470 NEXT K
480 NEXT J
500 END
