前の記事で、任意のdigitに数字を表示するテストをしました。
今回は、数値を任意の位置に表示するテストをします。表示範囲に右詰めで表示します。
Arduinoと8桁７セグメントLEDモジュールとの接続は、前の記事と同じです。
下の図のように、digit xから幅nl桁に数値を表示します。
スケッチです。
例として、digit5から4桁で0.5secごとにカウントアップする数値を右詰めで表示してみます。
数値を一旦文字列に変換し、Stringクラスで処理を行います。lnは実際の文字列の長さです。文字列から1文字ずつsubstring()でとりだします。取り出した文字は、数値に変換してLED表示します。ゼロ消しは、プログラムで行っています。(2022.09.13 スケッチの一部を修正しました。)
-------------------------------------------------------------------
/*
* Arduino MAX7219 7seg LED test
* 2022.09.13
* JH7UBC Keiji Hata
*/
#include <SPI.h>
#define CS_PIN 10
//CLK PIN13
//DIN PIN11
// MAX7219 Register Address
#define MAX7219_DECODE_MODE 0x09
#define MAX7219_INTENSITY 0x0a
#define MAX7219_SCAN_LIMIT 0x0b
#define MAX7219_SHUTDOWN 0x0C
#define MAX7219_DISPLAY_TEST 0x0f
void maxTransfer(uint8_t address, uint8_t value) {
digitalWrite(CS_PIN, LOW); // Start transfer.
SPI.transfer(address); // Send address.
SPI.transfer(value); // Send the value.
digitalWrite(CS_PIN, HIGH); // Finish transfer.
}
void MAX7219_INI(){
maxTransfer(MAX7219_DECODE_MODE, 0xff);// Code B decode for digits 7–0
maxTransfer(MAX7219_INTENSITY, 0x03); // Intensity
maxTransfer(MAX7219_SCAN_LIMIT, 0x07);// Display digits 01234567
maxTransfer(MAX7219_SHUTDOWN, 0x01);// Normal Operation
maxTransfer(MAX7219_DISPLAY_TEST, 0x00);// Normal Operation
}
void Clear_Display(){
for(uint8_t i=1;i<=8;i++){
maxTransfer(i,0x0f);
}
}
void setup() {
pinMode(CS_PIN, OUTPUT); // CS_Pin is OUTPUT Mode
digitalWrite(CS_PIN, HIGH); // CS＝HIGH
SPI.setBitOrder(MSBFIRST); // Reverse the SPI Data o/p.
SPI.begin(); // Start SPI
MAX7219_INI();
Clear_Display();
}
//x=表示開始digit(digit7-0)、nl=数値の最大長、num=表示する数値
//数値は右詰めで表示する
void printnum(uint8_t x,uint8_t nl,uint16_t num){
String s=String(num); //数値を文字列に変換
uint8_t ln=s.length();//文字列の長さ
int ix=ln-nl; //index初期値
uint8_t sx=x+1; //表示開始アドレス
for(uint8_t i=0;i<nl;i++){
int index=ix+i;
if(index<0){
maxTransfer(sx-i,0x0f);
}else{
String c=s.substring(index,index+1);//indexの文字を1個取り出す
uint8_t m = c.toInt();//文字列を数値に変換
maxTransfer(sx-i,m);
}
}
}
void loop() {
for(uint16_t i=0;i<10000;i++){
printnum(5,4,i);
delay(500);
}
}
-------------------------------------------------------------------
表示している様子です。
