算額（その355）

算額（その355）

福島県楢葉町北田 北田神社 明治27年(1894)
ならはの絵馬―村人の祈り― 018/036page
http://is2.sss.fukushima-u.ac.jp/fks-db/txt/10088.002/html/00018.html
福島県楢葉町北田には，北田天満宮と大山祇神社があるが北田神社はないようだ。

正三角形内に松円，松円の半円，竹円，梅円を入れる。梅円直径が 3 寸のとき，松円の直径を求めよ。

正三角形の一辺の長さを 1 とする。
松円の半径，中心座標を r1, (0, y1)
竹円の半径，中心座標を r2, (0, r2)
梅円の半径，中心座標を r3, (r3, y3)
とおき，以下の連立方程の解を求める。

include("julia-source.txt");

using SymPy

@syms r1::positive, y1::positive, r2::positive, r3::positive, x3::positive;

eq1 = (1 - r1/sqrt(Sym(3)))^2 + (y1 - r1)^2 - 4r1^2
eq2 = (1 - r1/sqrt(Sym(3)))^2 + (r1 - r2)^2 - (r1 + r2)^2
eq3 = (1 - r1/sqrt(Sym(3)) - x3)^2 + (r1 - r3)^2 - (r1 + r3)^2
eq4 = x3^2 + (r2 - r3)^2 - (r2 + r3)^2
eq5 = (sqrt(Sym(3)) - y1)/2 - r1;
res = solve([eq1, eq2, eq3, eq4, eq5], (r1, y1, r2, r3, x3))

   1-element Vector{NTuple{5, Sym}}:
    (sqrt(3)/4, sqrt(3)/2, 3*sqrt(3)/16, -9 + 21*sqrt(3)/4, -9/4 + 3*sqrt(3)/2)

res[1][1] |> println  # r1: 松円の半径
res[1][4] |> println  # r3: 梅円の半径

   sqrt(3)/4
   -9 + 21*sqrt(3)/4

res[1][1]/res[1][4] |> simplify |> println

   4*sqrt(3)/3 + 7/3

松円の半径（直径）は梅円の半径（直径）の (4√3 + 7)/3 倍である。
梅円の直径が 3 寸ならば，松円の直径は 4√3 + 7 寸である。

4√3 + 7

   13.928203230275509

   r1 = 0.433013; y1 = 0.866025; r2 = 0.32476; r3 = 0.0932667; x3 = 0.348076
   梅円が 3 寸のとき，松円は r1/r3 * 3 = 13.9282 寸

using Plots

function draw(more)
    pyplot(size=(500, 500), grid=false, aspectratio=1, label="", fontfamily="IPAMincho")
   (r1, y1, r2, r3, x3) = (sqrt(3)/4, sqrt(3)/2, 3*sqrt(3)/16, -9 + 21*sqrt(3)/4, -9/4 + 3*sqrt(3)/2)
   @printf("r1 = %g; y1 = %g; r2 = %g; r3 = %g; x3 = %g\n", r1, y1, r2, r3, x3)
   @printf("梅円が 3 寸のとき，松円は r1/r3 * 3 = %g 寸\n", 3r1/r3)
   plot([1, 0, -1, 1], [0, sqrt(3), 0, 0], color=:black, lw=0.5)
   circle(0, y1, r1, :green)
   circle(1 - r1/sqrt(3), r1, r1, :green, beginangle=120, endangle=300)
   circle(r1/sqrt(3) - 1, r1, r1, :green, beginangle=240, endangle=420)
   circle(0, r2, r2, :blue)
   circle(x3, r3, r3, :red)
   circle(-x3, r3, r3, :red)
   if more
       delta = (fontheight = (ylims()[2]- ylims()[1]) / 500 * 10 * 2) /3  # size[2] * fontsize * 2
       point(0, y1, " y1:\n 松円:r1", :green, :left, :vcenter)
       point(1 - r1/sqrt(3), r1, "(1-r1/√3,r1)", :green, :right, :vcenter)
       point(0, r2, " r2:\n 竹円:r2", :blue, :left, :vcenter)
       point(x3, r3, " 梅円:r3\n (x3,r3)", :red, :left, :vcenter)
       point(0, √3, " √3", :black)
       hline!([0], color=:black, lw=0.5)
       vline!([0], color=:black, lw=0.5)
   else
       plot!(showaxis=false)
   end
end;

算額（その354）

算額（その354）

福島県楢葉町北田 北田神社 明治27年(1894)
ならはの絵馬―村人の祈り― 018/036page
http://is2.sss.fukushima-u.ac.jp/fks-db/txt/10088.002/html/00018.html
福島県楢葉町北田には，北田天満宮と大山祇神社があるが北田神社はないようだ。

外円内に春夏秋冬の6円を入れる。春円，夏円の直径をそれぞれ 3 寸，4 寸としたとき，秋円の直径を求めよ。

外円の半径，中心座標を r0, (0, 0)
春円の半径，中心座標を r1, (0, r0 - r1)
夏円の半径，中心座標を r2, (x2, y2)
秋円の半径，中心座標を r3, (r3, y3)
冬円の半径，中心座標を r4, (0, r0 - 2r1 - r4)
とおき，以下の連立方程式の数値解を nlsolve() で求める。

include("julia-source.txt");

using SymPy

@syms r0::positive, r1::positive, r2::positive, x2::positive,
     y2::positive, r3::positive, y3::negative, r4::positive;

(r1, r2) = (3, 4) .// 2
eq1 = x2^2 + (r0 - r1 - y2)^2 - (r1 + r2)^2
eq2 = x2^2 + (r0 - 2r1 - r4 - y2)^2 - (r2 + r4)^2
eq3 = x2^2 + y2^2 - (r0 - r2)^2
eq4 = (x2 - r3)^2 + (y2 - y3)^2 - (r2 + r3)^2
eq5 = r3^2 + y3^2 - (r0 - r3)^2
eq6 = r3^2 + (r0 - 2r1 - r4 - y3)^2 - (r3 + r4)^2;
# solve([eq1, eq2, eq3, eq4, eq5, eq6]);

using NLsolve

function nls(func, params...; ini = [0.0])
   if typeof(ini) <: Number
       r = nlsolve((vout, vin) -> vout[1] = func(vin[1], params..., [ini]), ftol=1e-14)
       v = r.zero[1]
   else
       r = nlsolve((vout, vin)->vout .= func(vin, params...), ini, ftol=1e-14)
       v = r.zero
   end
   return v, r.f_converged
end;

function H(u)
   (r0, x2, y2, r3, y3, r4) = u
   return [
       x2^2 + (r0 - y2 - 3/2)^2 - 49/4,  # eq1
       x2^2 - (r4 + 2)^2 + (r0 - r4 - y2 - 3)^2,  # eq2
       x2^2 + y2^2 - (r0 - 2)^2,  # eq3
       (-r3 + x2)^2 - (r3 + 2)^2 + (y2 - y3)^2,  # eq4
       r3^2 + y3^2 - (r0 - r3)^2,  # eq5
       r3^2 - (r3 + r4)^2 + (r0 - r4 - y3 - 3)^2,  # eq6
   ]
end;

iniv = [28.0, 7.2, 8.0, 6.0, -5.2, 2.8]
res = nls(H, ini=iniv);

   r0 = 8.69972; x2 = 3.23607; y2 = 5.86635; r3 = 4.34164; y3 = -0.378172; r4 = 1.77267

秋円の直径は 8.68328 寸である。

using Plots

function draw(more)
    pyplot(size=(500, 500), grid=false, aspectratio=1, label="", fontfamily="IPAMincho")
   (r1, r2) = (3, 4) .// 2
   (r0, x2, y2, r3, y3, r4) = res[1]
   @printf("r0 = %g; x2 = %g; y2 = %g; r3 = %g; y3 = %g; r4 = %g\n", r0, x2, y2, r3, y3, r4)
   @printf("秋円直径 = %g 寸\n", 2r3)
   plot()
   circle(0, 0, r0, :black)
   circle(0, r0 - r1, r1, :green)
   circle(x2, y2, r2)
   circle(-x2, y2, r2)
   circle(r3, y3, r3, :gray)
   circle(-r3, y3, r3, :gray)
   circle(0, r0 - 2r1 - r4, r4, :orange)
   if more
       delta = (fontheight = (ylims()[2]- ylims()[1]) / 500 * 10 * 2) /3  # size[2] * fontsize * 2
       point(0, r0 - r1, "春:r1\nr0-r1", :green, :left, :vcenter)
       point(x2, y2, "夏:r2,(x2,y2)", :red, :center, delta=-delta)
       point(0, r0 - 2r1 - r4, "冬:r4\nr0-2r1-r4", :orange, :left, :vcenter)
       point(r3, y3, "秋:r3,(r3,y3)", :gray, :center, delta=-delta)
       hline!([0], color=:black, lw=0.5)
       vline!([0], color=:black, lw=0.5)
   else
       plot!(showaxis=false)
   end
end;

算額（その353）

算額（その353）

二十九 群馬県高崎市山名町 八幡宮 文化11年(1814)
群馬県和算研究会:群馬の算額，上武印刷株式会社，高崎市，1987年3月31日.

群馬県高崎市山名町 山名八幡宮 文化11年(1814)
http://takasakiwasan.web.fc2.com/gunnsann/g029-4.html

キーワード：円4個，直角三角形

鈎股弦（直角三角形）内に，大円 1 個と小円 3 個を入れる。鈎の長さが 3 寸のとき，股の長さはいかほどか。

include("julia-source.txt");

using SymPy

@syms 鈎::positive, 股::positive, x1::positive, r1::positive,
     r2::positive, x2::positive, y2::positive;

鈎 = 3
eq1 = (x1 - r2)^2 + (r1 - r2)^2 - (r1 + r2)^2
eq2 = (x1 - r2)^2 + (3r2 - r1)^2 - (r1 + r2)^2
eq3 = (x1 - x2)^2 + (y2 - r1)^2 - (r1 + r2)^2
eq4 = (x2 - r2)^2 + (y2 - 3r2)^2 - 4r2^2
eq5 = distance(0, 鈎, 股, 0, x1, r1) - r1^2
eq6 = distance(0, 鈎, 股, 0, x2, y2) - r2^2;
# solve([eq1, eq2, eq3, eq4, eq5, eq6]);

using NLsolve

function nls(func, params...; ini = [0.0])
   if typeof(ini) <: Number
       r = nlsolve((vout, vin) -> vout[1] = func(vin[1], params..., [ini]), ftol=1e-14)
       v = r.zero[1]
   else
       r = nlsolve((vout, vin)->vout .= func(vin, params...), ini, ftol=1e-14)
       v = r.zero
   end
   return v, r.f_converged
end;

function H(u)
   (股, r1, x1, r2, x2, y2) = u
   return [
       (r1 - r2)^2 - (r1 + r2)^2 + (-r2 + x1)^2,  # eq1
       (-r1 + 3*r2)^2 - (r1 + r2)^2 + (-r2 + x1)^2,  # eq2
       (-r1 + y2)^2 - (r1 + r2)^2 + (x1 - x2)^2,  # eq3
       -4*r2^2 + (-3*r2 + y2)^2 + (-r2 + x2)^2,  # eq4
       -r1^2 + (r1 - 3*(3*r1 - x1*股 + 股^2)/(股^2 + 9))^2 + (x1 - 股*(-3*r1 + x1*股 + 9)/(股^2 + 9))^2,  # eq5
       -r2^2 + (x2 - 股*(x2*股 - 3*y2 + 9)/(股^2 + 9))^2 + (y2 - 3*(-x2*股 + 3*y2 + 股^2)/(股^2 + 9))^2,  # eq6
   ]
end;

iniv = [big"4.0", 1, 2, 0.5, 1.2, 2]
res = nls(H, ini=iniv);

   股 = 3.71231;  r1 = 0.782752;  x1 = 1.49835;  r2 = 0.391376;  x2 = 0.883366;  y2 = 1.78293

using Plots

function draw(more)
   pyplot(size=(500, 500), grid=false, aspectratio=1, label="", fontfamily="IPAMincho")
   鈎 = 3
   (股, r1, x1, r2, x2, y2) = res[1]
   @printf("股 = %g;  r1 = %g;  x1 = %g;  r2 = %g;  x2 = %g;  y2 = %g\n", 股, r1, x1, r2, x2, y2)
   plot([0, 股, 0, 0], [0, 0, 鈎, 0], color=:black, lw=0.5)
   circle(x1, r1, r1, :blue)
   circle(r2, r2, r2)
   circle(r2, 3r2, r2)
   circle(x2, y2, r2)
   if more
       delta = (fontheight = (ylims()[2]- ylims()[1]) / 500 * 10 * 2) /3  # size[2] * fontsize * 2
       point(x1, r1, "大円:r1,(x1, r1)", :blue, :center, delta=-delta)
       point(r2, r2, "小円:r2\n(r2,r2)", :green, :center, delta=-delta)
       point(r2, 3r2, "(r2,3r2)", :red, :center, delta=-delta)
       point(x2, y2, "(x2,x2)", :red, :center, delta=-delta)
       point(股, 0, " 股", :black, :left, :bottom)
       point(0, 鈎, " 鈎", :black, :left, :bottom)
       hline!([0], color=:black, lw=0.5)
       vline!([0], color=:black, lw=0.5)
   else
       plot!(showaxis=false)
   end
end;