算額（その1141）

算額（その1141）

二五 武州妻沼 聖天宮 文政11年(1828)
埼玉県立図書館：埼玉県史料集 第二集『埼玉の算額』，昭和44年，誠美堂印刷所，埼玉県与野市.
キーワード：円5個，外円，弦

外円の中に水平な弦を引き，大円，中円，小円を容れる。大円，中円の直径がそれぞれ 10 寸，2.5 寸のとき，小円の直径はいかほどか。

弦と y 軸の交点座標を (0, y); y = 2r2 - R
外円の半径と中心座標を R, (0, 0)
大円の半径と中心座標を r1, (x1, y + r1)
中円の半径と中心座標を r2, (x2, y + r2), (0, y - r2)
小円の半径と中心座標を r3, (0, y + r3)
とおき以下の連立方程式を解く。

include("julia-source.txt")

using SymPy

@syms R::positive, y::positive, r1::positive, x1::positive,
     r2::positive, x2::negative, r3::positive, x3::positive
y = 2r2 - R
eq1 = x1^2 + (y + r1)^2 - (R - r1)^2
eq2 = x2^2 + (y + r2)^2 - (R - r2)^2
eq3 = x3^2 + (y + r3)^2 - (R - r3)^2
eq4 = (x1 - x2)^2 + (r1 - r2)^2 - (r1 + r2)^2
eq5 = (x3 - x1)^2 + (r1 - r3)^2 - (r1 + r3)^2;
(R, x1, x2, r3, x3) = solve([eq1, eq2, eq3, eq4, eq5], (R, x1, x2, r3, x3))[1];

R  |> println
x1 |> factor |> println
x2 |> factor |> println
r3 |> println
x3 |> factor |> println

   (2*r1 + r2)^2/(4*r1)
   r2^(3/2)/sqrt(r1)
   -sqrt(r2)*(2*r1 - r2)/sqrt(r1)
   r1^2*r2/(r1 + r2)^2
   sqrt(r2)*(2*r1^2 + r1*r2 + r2^2)/(sqrt(r1)*(r1 + r2))

小円の半径 r3 は，大円，中円の半径 r1, r2 により r1^2*r2/(r1 + r2)^2 倍である。
大円，中円の直径がそれぞれ 10 寸，2.5 寸のとき，小円の直径は 1.6 寸である。

その他のパラメータは以下の通りである。

   R = 6.32812; r1 = 5; x1 = 0.625;  r2 = 1.25;  x2 = -4.375;  r3 = 0.8;  x3 = 4.625

function draw(r1, r2, more=false)
    pyplot(size=(500, 500), grid=false, aspectratio=1, label="", fontfamily="IPAMincho")
   R  = (2r1 + r2)^2/4r1
   x1 = r2^(3/2)/√r1
   x2 = √r2*(r2 - 2r1)/√r1
   r3 = r1^2*r2/(r1 + r2)^2
   x3 = √r2*(2r1^2 + r1*r2 + r2^2)/(√r1*(r1 + r2))
   @printf("大円，中円の直径が %g，%g のとき，小円の直径は %g である。\n", 2r1, 2r2, 2r3)
   @printf("R = %g; r1 = %g; x1 = %g;  r2 = %g;  x2 = %g;  r3 = %g;  x3 = %g\n", R, r1, x1, r2, x2, r3, x3)
   y = 2r2 - R
   plot()
   circle(0, 0, R)
   circle(x1, y + r1, r1, :magenta)
   circle(0, y - r2, r2, :blue)
   circle(x2, y + r2, r2, :blue)
   circle(x3, y + r3, r3, :green)
   x = sqrt(R^2 - y^2)
   segment(-x, y, x, y, :orange)
   if more
       delta = (fontheight = (ylims()[2]- ylims()[1]) / 500 * 10 * 2) /3  # size[2] * fontsize * 2
       hline!([0], color=:gray80, lw=0.5)
       vline!([0], color=:gray80, lw=0.5)
       point(0, 0, "", :red)
       point(0, R, "R", :red, :center, :bottom, delta=delta)
       point(R, 0, " R", :red, :left, :bottom, delta=delta/2)
       point(0, y, "y", :black, :center, :bottom, delta=delta)
       point(x1, y + r1, "大円:r1,(x1,y+r1)", :magenta, :center, :bottom, delta=delta/2)
       point(x2, y + r2, "中円:r2\n(x2,y+r2)", :blue, :center, :bottom, delta=delta/2)
       point(0, y - r2, "中円:r2\n(0,y-r2)", :blue, :center, delta=-delta/2)
       point(x3, y + r3, "小円:r3,(x3,y+r3)", :black, :right, :vcenter, deltax=-delta)
   end
end;