算額（その1094）

算額（その1094）

五十三 岩手県一関市 舞草観音堂  天保14年(1843)より後（?）
山村善夫：現存 岩手の算額，昭和52年1月30日，熊谷印刷，盛岡市.
http://www.wasan.jp/yamamura/yamamura.html
キーワード：円4個，正三角形，正方形

全円に内接する正三角形と水平な弦を引き，分割された領域に等円 3 個，楕円 1 個を容れる。等円の直径が 与えられたときに楕円の長径を求めよ。

全円の半径と中心座標を R, (0, 0)
等円の半径と中心座標を r, (x, 2b - R/2 - r), (0, 2b - R/2 + r)
楕円の長半径，短半径と中心座標を a, b, (0, b - R/2); b = r
最終的な図を描くのには不要であるが，楕円と正三角形の接点の座標を (x0, y0)
とおき，以下の連立方程式を解く。

include("julia-source.txt")

using SymPy

@syms R::positive, r::positive, x::positive, y::positive,
     a::positive, b::positive, x0::positive, y0::positive
y = 2b - R/2 - r
eq1 = x0^2/a^2 + (y0 - b + R/2)^2/b^2 - 1
eq2 = -b^2*x0/(a^2*(y0 - b + R/2)) + √Sym(3)
eq3 = (y0 - b + R/2)/x0 - 1/√Sym(3) # 0.3083756345177664
eq3 = (y0 + R/2)/(√Sym(3)R/2 - x0) -√Sym(3)
eq4 = dist2(0, R, √Sym(3)R/2, -R/2, x, y, r)
eq5 = dist2(0, R, √Sym(3)R/2, -R/2, 0, r + 2b - R/2, r)
eq6 = x^2 + y^2 - (R - r)^2
eq7 = 2r - (3R/2 - 2b - r)
res = solve([eq1, eq2, eq3, eq4, eq5, eq6], (R, x, a, b, x0, y0))[1]

    (9*r/2, 2*sqrt(3)*r, 3*sqrt(3)*r/2, 15*r/8, 18*sqrt(3)*r/13, 9*r/26)

楕円の長半径 a は，等円の半径 r の 3√3/2 倍である。
等円の直径が 1 寸の解き，楕円の長径は 3√3/2 = 2.598076211353316 寸である。

山村は根拠なく「側円長径=等円径×3」と提案しているが，もちろん誤りである。

その他のパラメータは以下のとおりである。

   r = 0.5;  R = 2.25;  x = 1.73205;  y = 0.25;  a = 1.29904;  b = 0.9375;  x0 = 1.19911;  y0 = 0.173077

function draw(more=false)
   pyplot(size=(500, 500), grid=false, aspectratio=1, label="", fontfamily="IPAMincho")
   r = 1/2
   (R, x, a, b, x0, y0) = (9*r/2, 2*sqrt(3)*r, 3*sqrt(3)*r/2, 15*r/8, 18*sqrt(3)*r/13, 9*r/26)
   y = 2b - R/2 - r
   l = √3R/2
   @printf("等円の直径が %g のとき，楕円の長径は %g である。\n", 2r, 2a)
   @printf("r = %g;  R = %g;  x = %g;  y = %g;  a = %g;  b = %g;  x0 = %g;  y0 = %g\n", r, R, x, y, a, b, x0, y0)
   plot([l, 0, -l, l], [ -R/2, R, -R/2, -R/2], color=:blue, lw=0.5)
   circle(0, 0, R, :magenta)
   circle2(x, y, r)
   circle(0, 2b - R/2 + r, r)
   ellipse(0, b - R/2, a, b, color=:green)
   segment(-sqrt(R^2 - (2b - R/2)^2), 2b - R/2, sqrt(R^2 - (2b - R/2)^2), 2b - R/2)
   if more
       delta = (fontheight = (ylims()[2]- ylims()[1]) / 500 * 10 * 2) /3  # size[2] * fontsize * 2
       hline!([0], color=:gray80, lw=0.5)
       vline!([0], color=:gray80, lw=0.5)
       point(0, -R/2, "-R/2", :green, :center, delta=-delta/2)
       point(0, 2b - R/2, "2b-R/2", :green, :center, delta=-delta/2)
       point(0, 2b - R/2 + r, "等円:r\n(0,2b-R/2+r)", :red, :center, delta=-delta/2)
       point(x, 2b - R/2 - r, "等円:r\n(0,2b-R/2-r)", :red, :center, delta=-delta/2)
       point(0, b - R/2, "楕円:a,b,(0,b-R/2)", :green, :center, delta=-delta/2)
       point(R, 0, " R", :magenta, :left, :bottom, delta=delta/2)
   end
end;

算額（その1093）

算額（その1093）

五十二 岩手県一関市 舞草観音堂 正慶山聖観世音堂 天保14年(1843)
山村善夫：現存 岩手の算額，昭和52年1月30日，熊谷印刷，盛岡市. http://www.wasan.jp/yamamura/yamamura.html
キーワード：円4個，正三角形，正方形

正方形の中に正三角形，大円 3 個，小円 1 個を容れる。小円の直径が与えられたとき，大円の直径を求めよ。

正方形の一辺の長さを a
正方形の辺上にある正三角形の頂点座標を (b, 0), (a, a - b)
大円の半径と中心座標を r1, (r1, r1), (a - r1, r1), (a - r1, a - r1)
小円の半径と中心座標を r2, (r2, a - r2)
とおき，以下の連立方程式を解く。

include("julia-source.txt")

using SymPy

@syms a::positive, b::positive, r1::positive, r2::positive
eq1 = √Sym(2)r1 + r1 + (a - b)√Sym(6)/2 + r2 + √Sym(2)r2 - √Sym(2)a
eq2 = 2(a - b) - (a - b)√Sym(2) - 2r1
eq3 = dist2(r2*(1 + √Sym(2))/√Sym(2), a - r2*(1 + √Sym(2))/√Sym(2), b, 0, r1, r1, r1);

まず，eq1, eq2 を解き a, b を求める。

res = solve([eq1, eq2], (a, b));

eq3 の a, b に，上で求めた a, b を代入する。方程式は分数式になるので，分子のみを使用する（分子 = 0 を解く）。

eq13 = eq3(a => res[a], b => res[b]) |> simplify |> numerator;

eq13 を r1 について解く（既知として与えられる r2 が含まれる式になる）。

ans_r1 = solve(eq13, r1)[1]
ans_r1 |> println

   r2*(-6081993113*sqrt(3) - 7322183923*sqrt(2) - 2*sqrt(-30721933218127447098*sqrt(3) - 37624610574115488280*sqrt(2) + 21722579043120417140*sqrt(6) + 53211949240534761996) + 4227464859*sqrt(6) + 10534321083)/(2*(-29290843252*sqrt(3) - 35584075994*sqrt(2) + 20544475854*sqrt(6) + 50733228709))

r2 にかかる係数は長精度実数演算が必要であるが，実数値 1.62035849881469 である。
上記のように r2* の形だと簡約化できないが係数部分だけを対象にすると簡約化できる。
この係数は「術」で述べられているものと同じである。

@syms d
z = ans_r1/r2
z = apart(z, d) |> factor
z |> println

   -(-9 - 5*sqrt(3) + 5*sqrt(2) + 3*sqrt(6))/2

a, b を求めるための r2 にかかる係数は以下のように求めることができる。

res[a](r1 => r2*z, r2 => 1).evalf() |> println

   9.26430077012849

res[b](r1 => r2*z, r2 => 1).evalf() |> println

   3.73205080756888

r2 が与えられると，r1, a, b は r2 の低数倍として以下のように計算できる。

(r1, a, b) = r2 .* [1.62035849881469, 9.26430077012849, 3.73205080756888];

小円の直径が 1 のとき，大円の直径は 1.62035849881469 である。

上述のように，「術」に述べられている式は，正しいものである。しかし，山村の解説では，最終的に「大径 = 小径×6.463284」となっているが，途中の式で「方斜率」を掛け忘れている。正しくは以下のように小径にかかる係数は 1.6203584988146877 である。

小径 = 1
方斜率 = √2
天 = √3
(天*5 + 9 - (天*3 + 5)*方斜率) * 小径 / 2

   1.6203584988146877

function draw(more=false)
   pyplot(size=(500, 500), grid=false, aspectratio=1, label="", fontfamily="IPAMincho")
   r2 = 1/2
   (r1, a, b) = r2 .* [1.62035849881469, 9.26430077012849, 3.73205080756888]
   @printf("小円の直径が %g のとき，大円の直径は %g である。\n", 2r2, 2r1)
   @printf("r2 = %g;  r1 = %g;  a = %g;  b = %g\n", r2, r1, a, b)
   plot([0, a, a, 0, 0], [0, 0, a, a, 0], color=:blue, lw=0.5)
   plot!([r2*(1 + √2)/√2, b, a, r2*(1 + √2)/√2], [a - r2*(1 + √2)/√2, 0, a - b, a - r2*(1 + √2)/√2], color=:green, lw=0.5)
   circle(r1, r1, r1)
   circle(a - r1, r1, r1)
   circle(a - r1, a - r1, r1)
   circle(r2, a - r2, r2)
   if more
       delta = (fontheight = (ylims()[2]- ylims()[1]) / 500 * 10 * 2) /3  # size[2] * fontsize * 2
       hline!([0], color=:gray80, lw=0.5)
       vline!([0], color=:gray80, lw=0.5)
       point(r1, r1, "大円:(r1,r1)", :red, :center, delta=-delta/2)
       point(a - r1, r1, "大円:(a-r1,r1)", :red, :center, delta=-delta/2)
       point(a - r1, a - r1, "大円:(a-r1,a-r1)", :red, :center, delta=-delta/2)
       point(r2, a - r2, "小円:(r2,a-r2)", :magenta, :center, delta=-delta/2)
       point(b, 0, "b ", :green, :right, :bottom, delta=delta/2)
       point(a, a - b, "(a,a-b)  ", :green, :right, :vcenter, delta=-delta)
   end
end;