こんにちはー、ちーでーす。＼(^O^)／
ちー達とは、
関係のうすいグループだけど、
数年前、ロケットの書き込みがあったの。
掲載させていただきまーす。(*^_^*)
良かったら、見てね。(*^_^*)
俺、pure_love_shigeo。イケてる東京hikky_houseだぜ、ベイビィ！！
さーてと、今日はイケてる東京hikky_houseの(仮想)月ロケット"アリス拾號"、
の軌道計算だぜ、ベイビィ！！
(東京hikky_houseの近況報告は次回ブログに掲載させて頂きます。)
月へ行くロケット"アリス拾號"を赤道上接線方向に向けて発射させました。
その軌道を見ましょう。
｜
・・・
・ ｜ ・
・ ｜ ・↑
｜ ↑
・ ｜ ↑
－－－－－（月）－－－－－－－・－－－＋－－－＊－－
・ ｜ ・
｜ 地球
・ ｜ ・
・ ｜ ・
・・・ ＊はロケット
｜
[プログラム]
今回は、フリーウエア"十進BASIC for Windows"インタプリンターを使用して作成しました。
よろしかったら、"ベクター"サイト等でダウンロード(そして解凍)し、十進BASIC立ち上げた上で、
入力・実行を行って下さい。
10 !' MOON ROCKET ORBIT
18 SET WINDOW -850,850,-850,850
22 PLOT LINES :-850,0;200,0
25 PLOT LINES :0,200;0,-200
26 SET COLOR 9
27 DRAW DISK WITH SCALE(10)*SHIFT(0,0)
30 SET COLOR 6
33 PLOT POINTS: -602,0
50 READ V1,V0,DT,TT
60 DATA 0,1.4008,0.02,1050
110 LET T1=0
120 LET T=0
130 LET X=1
140 LET Y=0
150 LET VX=V1
160 LET VY=V0
500 SET COLOR 7
1500 LET XH=X+VX*DT/2
1510 LET YH=Y+VY*DT/2
1600 LET R=SQR(XH*XH+YH*YH)
1610 LET R3=R*R*R
1700 LET RM=SQR((60.25+XH)*(60.25+XH)+YH*YH)
1710 LET R4=RM*RM*RM
1800 LET AX=-XH/R3-(60.25+XH)/(R4*81)
1810 LET AY=-YH/R3-YH/(R4*81)
1900 LET VX=VX+AX*DT
1910 LET VY=VY+AY*DT
2000 LET X=XH+VX*DT/2
2010 LET Y=YH+VY*DT/2
2400 LET T=T+DT
2420 LET T1=T1+DT
2450 PLOT POINTS: X*10,Y*10
2500 IF T＜0.4 THEN 1500
3300 LET T=T-0.4
3450 PRINT T1," X=";X," Y=";Y
3451 PRINT " ","VX=";VX,"VY=";VY
3455 PRINT " "
4000 IF T1＜TT THEN 1500
5000 END
※大小記号は＜,＞と全角で表示しています。
●参考
(地球の半径を１、地球からの月の距離は地球の半径の約60.25倍、月の質量は地球の約1/81とする。)
50 READ V1,V0,DT,TT
60 DATA 0,1.4008,0.02,1050
x方向の初速度 0、y方向の初速度 1.4008、微少時間DTを0.02、最終位置までに達する時間を1050とする。
(1050はちょっと多めです。)
1500 LET XH=X+VX*DT/2
1510 LET YH=Y+VY*DT/2
微少時間の半分の経った所のx,yの位置をを求める。
位置＝微少時間たつ前の位置＋速度＊微少時間(今回は半分)
1600 LET R=SQR(XH*XH+YH*YH)
ロケットの地球からの距離
1700 LET RM=SQR((60.25+XH)*(60.25+XH)+YH*YH)
ロケットの月からの距離
1610 LET R3=R*R*R
1710 LET R4=RM*RM*RM
1800 LET AX=-XH/R3-(60.25+XH)/(R4*81)
1810 LET AY=-YH/R3-YH/(R4*81)
AX,AYは微少時間半分過ぎたときのロケットのX,Y方向の加速度を求めています。
※地球と月の引力がロケットの加速度に影響を与えています。微少時間の中間点でこのように
求めると精度が上がるそうです。
万有引力の法則で、一般に地球の中心からの距離がr(m)の点における1kgの物体の受ける万有引力Ｆは
Ｇ＊１＊Ｍe
Ｆ＝ －－－－－－－－
r*r
宇宙のスケール、地球・月の大きさや重さから見たら1kgも1tも差は超々微少。ゆえに、
地球や月からロケットにかかる引力の力は、
・地球から Ｇ＊Ｍe ・月から Ｇ＊Ｍm
Ｆe ＝ －－－－－－ Ｆm ＝ －－－－－－
r*r r*r
とする。
引力も、力も、結局は加速度の力(=加速度)である。ゆえ、
Ｇ＊Ｍe ｘ(座標) Ｇ＊Ｍm 60.25+ｘ(座標)
Ax ＝ － －－－－－－ ＊ －－－－－－－ － －－－－－－ ＊ －－－－－－－－
r*r r r(m) * r(m) r(m)
↑ ↑ ↑ ↑
地球より離れる x方向のベクトル ロケットは － x方向のベクトル
ていくので－ 分解 の方向に進んでいる 分解。月から見たら ゆえ 月も － かなり離れている。
出発直後のロケットの対する地球・月の引張るベクトル矢印を考えると何となくイメージが付くよ。
同様に
Ｇ＊Ｍe y(座標) Ｇ＊Ｍm y(座標)
Ay ＝ － －－－－－ ＊ －－－－－ － －－－－－－ ＊ －－－－－－
r*r r r(m) * r(m) r(m)
行きの途中まではこれで良いが、特に帰りなんかは判らないが、途中変数値の＋－反転などがあり、
どーやら、この式で上手く行く様です。
Ｇは万有引力定数、Ｍeは地球の質量、Ｍmは月の質量。そこで、ＭＫＳ単位系を用いると
Ｇ*Ｍe／(r*r)＝９．８m/s*sである事を考慮して、今Ｒ＝１になるようにしたのであるから、
Ｇ*Me=１になるように定める事にする。この時宇宙第一速度(7.90*10^3 m/s)が速度の単位１となる。
又、時間の単位１は約806.2秒となります。
この事を考えると、上のプログラムの4つの式が出来ます。
なんとなく、幾らか判ってきた様な感じが出てきてくれればよいなーと思ってます。
1900 LET VX=VX+AX*DT
1910 LET VY=VY+AY*DT
微少時間x,yの各方向の速度を求める。
この式を参考に。
速度＝前の速度＋加速度＊微少時間
位置見たく2回に分けて行わず、1回でＤＴ分の計算を行っている。
2000 LET X=XH+VX*DT/2
2010 LET Y=YH+VY*DT/2
2回に分けたx,yの現在位置の2回目(後半)を行っています。
[参考文献]
物理精義Ⅱ 吉本 市 先生 著 培風館 [1974(初版).1976(初版 第５刷)]
俺のブログ読んでくれて、アリガトよ。
本日はこれにて失礼するぜ。
これからもヨロシク。ベィビィ！！
以上
閲覧ありがとうございまーす。(*^_^*)
今日はこれで、失礼いたしまーす。ヽ(^o^)／
