goo

CPUの使用率取得

◆一覧リスト
HSP Ver3.0
HSP Ver2.61
ブログ関連
その他
★人気blogランキング

「CPUの使用率取得」
CPUの使用率の取得について。

以下、メモです。
2008/01/28 訂正
1000ms毎にCPUの使用率(%)を測定
左ドラッグでウィンドウ移動
右クリックで終了
/* ----------------------------------------------------------------------------
	CPU使用率取得モジュール
	GetPerCPU time
		time:取得時間
		戻り値:使用率(実数値)
   ---------------------------------------------------------------------------- */
#module GetCPUPer
#uselib "pdh.dll"
#func PdhOpenQuery "PdhOpenQuery" int,int,var
#func PdhAddCounter "PdhAddCounterA" int,var,int,var
#func PdhCollectQueryData "PdhCollectQueryData" int
#func PdhGetFormattedCounterValue "PdhGetFormattedCounterValue" int,int,int,var
#func PdhCloseQuery "PdhCloseQuery" int
#func PdhBrowseCounters "PdhBrowseCountersA" var

#define 	PDH_FMT_DOUBLE		0x200

#defcfunc GetPerCPU int time
	dim FmtValue,4 : cpu = 0f
	PdhOpenQuery 0, 0, hQuery
	s="¥¥Processor(_Total)¥¥% Processor Time"
	PdhAddCounter hQuery, s, 0, hCounter
	PdhCollectQueryData hQuery
	await time
	PdhCollectQueryData hQuery
	PdhGetFormattedCounterValue hCounter, PDH_FMT_DOUBLE, NULL, FmtValue
	dupptr cpu,varptr(FmtValue)+8,8,3
	PdhCloseQuery hQuery
return cpu
#global
/* end of GetCPUPer ----------------------------------------------------------- */

#define		WM_LBUTTONDOWN		0x0201
#define		WM_RBUTTONDOWN		0x0204
#define		WM_NCLBUTTONDOWN	0x00A1
#define		HTCAPTION		2

	bgscr 0,104,20 : gsel 0,2
	oncmd gosub *LBUTTONDOWN,WM_LBUTTONDOWN
	oncmd *RBUTTONDOWN,WM_RBUTTONDOWN
	//dim PDH_BROWSE_DLG_CONFIG,10
	//PdhBrowseCounters PDH_BROWSE_DLG_CONFIG
	font "",12
	repeat
       	redraw 0
		time = GetPerCPU(1000)
		color : boxf
		color 0,0,255 : boxf 2,2,time,16
		color 255,255,255: pos 3,3: mes strf("%7.2f %%",time)
		redraw 1
	loop

//マウス左ドラッグでウィンドウを移動
*LBUTTONDOWN
	sendmsg hwnd,WM_NCLBUTTONDOWN,HTCAPTION,0
return

//右クリックで終了
*RBUTTONDOWN
end
コメント ( 4 ) | Trackback ( 0 )
« ファイルのド... 解像度の変更 »
 
コメント
 
 
 
モジュールの使用について (mono)
2008-05-19 16:02:41
はじめまして。
HSPを勉強しておりまして、
このブログを参考にさせていただいております。
連絡先が分からなかったので、
こちらのコメントに失礼いたします。

現在お仕事でソースコードも公開する予定で
フリーソフトを製作してます。、
その中にこのCPU使用率取得モジュールを
使わせていただきたいのですが、
hiroさんのお名前とこのブログのURLを
ソース中に記載して、使わせていただいても
よろしいでしょうか?

突然のお願いですみませんが、
どうぞ宜しくお願いします。
 
 
 
モジュールの使用について (hiro)
2008-05-20 21:40:35
コメントありがとうございます。

モジュールの件ですが、ご自由に使っていただいて結構ですよ。
名前・URLの記載も必要ありませんので。
 
 
 
Unknown (mono)
2008-05-21 16:24:07
ご快諾どうもありがとうございます!
早速使わせていただきます。
 
 
 
Unknown (j19)
2010-01-06 17:07:47
このモジュールを使用させていただいてよろしいでしょうか?いまソフトを製作をしておりましてCPUの使用率を表示しようかなと思っております。
 
コメントを投稿する
 
名前
タイトル
URL
コメント
コメント利用規約に同意の上コメント投稿を行ってください。

数字4桁を入力し、投稿ボタンを押してください。